seth: delta -> riffdiff

4 files changed, 64 insertions, 2 deletions

diff --git a/modules/default.nix b/modules/default.nix
index e8a1832..c599041 100644
--- a/modules/default.nix
+++ b/modules/default.nix
@@ -1,6 +1,7 @@
 {
   imports = [
     ./darwin
+    ./home
     ./nixos
   ];
 }
diff --git a/modules/home/default.nix b/modules/home/default.nix
new file mode 100644
index 0000000..408e172
--- /dev/null
+++ b/modules/home/default.nix
@@ -0,0 +1,5 @@
+{
+  flake.homeModules = {
+    riff = ./riff.nix;
+  };
+}
diff --git a/modules/home/riff.nix b/modules/home/riff.nix
new file mode 100644
index 0000000..3a3e748
--- /dev/null
+++ b/modules/home/riff.nix
@@ -0,0 +1,49 @@
+# TODO: Upstream this
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+let
+  cfg = config.programs.git.riff;
+  cfg' = config.programs.git;
+
+  exe = baseNameOf (lib.getExe cfg.package);
+in
+{
+  options.programs.git.riff = {
+    enable = lib.mkEnableOption "diff filtering through riff";
+    package = lib.mkPackageOption pkgs "riffdiff" { };
+  };
+
+  config = lib.mkIf cfg.enable {
+    assertions = [
+      {
+        assertion =
+          let
+            enabled = [
+              cfg'.delta.enable
+              cfg'.diff-so-fancy.enable
+              cfg'.difftastic.enable
+              cfg.enable
+            ];
+          in
+          lib.count lib.id enabled <= 1;
+        message = "Only one of 'programs.git.delta.enable' or 'programs.git.difftastic.enable' or 'programs.git.diff-so-fancy.enable' or `programs.git.riff.enable` can be set to true at the same time.";
+      }
+    ];
+
+    home.packages = [ cfg.package ];
+
+    programs.git.iniContent = {
+      pager = {
+        diff = exe;
+        log = exe;
+        show = exe;
+      };
+
+      interactive.diffFilter = exe + " --color=on";
+    };
+  };
+}
diff --git a/users/seth/programs/git.nix b/users/seth/programs/git.nix
index b0b90a3..9b8ec53 100644
--- a/users/seth/programs/git.nix
+++ b/users/seth/programs/git.nix
@@ -1,8 +1,15 @@
-{ config, lib, ... }:
+{
+  config,
+  lib,
+  inputs,
+  ...
+}:
 let
   cfg = config.seth.programs.git;
 in
 {
+  imports = [ inputs.self.homeModules.riff ];
+
   options.seth.programs.git = {
     enable = lib.mkEnableOption "Git configuration settings" // {
       default = config.seth.enable;
@@ -38,7 +45,7 @@ in
       git = {
         enable = true;
 
-        delta.enable = true;
+        riff.enable = true;
 
         extraConfig = {
           init = {