4 files changed, 73 insertions, 0 deletions
diff --git a/overlay/btop.nix b/overlay/btop.nix
new file mode 100644
index 0000000..b2a5b24
--- /dev/null
+++ b/overlay/btop.nix
@@ -0,0 +1,14 @@
+_: prev: {
+  btop =
+    if prev.stdenv.isLinux
+    then
+      prev.symlinkJoin {
+        inherit (prev.btop) passthru;
+        name = "btop-nodesktop";
+        paths = [prev.btop];
+        postBuild = ''
+          rm $out/share/applications/btop.desktop
+        '';
+      }
+    else prev.btop;
+}
diff --git a/overlay/default.nix b/overlay/default.nix
new file mode 100644
index 0000000..24e3420
--- /dev/null
+++ b/overlay/default.nix
@@ -0,0 +1,15 @@
+{
+  flake.overlays.default = final: prev:
+    prev.lib.composeManyExtensions
+    (
+      prev.lib.pipe ./. [
+        builtins.readDir
+        builtins.attrNames
+
+        (builtins.filter (n: n != "default.nix"))
+        (map (f: import ./${f}))
+      ]
+    )
+    final
+    prev;
+}
diff --git a/overlay/discord.nix b/overlay/discord.nix
new file mode 100644
index 0000000..cb651cd
--- /dev/null
+++ b/overlay/discord.nix
@@ -0,0 +1,30 @@
+_: prev: let
+  mkOverride = d: let
+    # TODO: re-enable openASAR when gnome wayland decorations work with it
+    d' = d; #.override {withOpenASAR = true;};
+    inherit (d') pname;
+
+    desktopName =
+      if pname == "discord-canary"
+      then "Discord Canary"
+      else "Discord";
+
+    flags = "--enable-gpu-rasterization --enable-zero-copy --enable-gpu-compositing --enable-native-gpu-memory-buffers --enable-oop-rasterization --enable-features=UseSkiaRenderer,WaylandWindowDecorations";
+
+    desktopItem = prev.makeDesktopItem {
+      name = pname;
+      exec = "${builtins.replaceStrings [" "] [""] desktopName} ${flags}";
+      icon = pname;
+      inherit desktopName;
+      genericName = d'.meta.description;
+      categories = ["Network" "InstantMessaging"];
+      mimeTypes = ["x-scheme-handler/discord"];
+    };
+  in
+    if prev.stdenv.isLinux
+    then d'.overrideAttrs (_: {inherit desktopItem;})
+    else d';
+in {
+  discord = mkOverride prev.discord;
+  discord-canary = mkOverride prev.discord-canary;
+}
diff --git a/overlay/fish.nix b/overlay/fish.nix
new file mode 100644
index 0000000..4e7fffc
--- /dev/null
+++ b/overlay/fish.nix
@@ -0,0 +1,14 @@
+_: prev: {
+  fish =
+    if prev.stdenv.isLinux
+    then
+      prev.symlinkJoin {
+        inherit (prev.fish) passthru;
+        name = "fish-nodesktop";
+        paths = [prev.fish];
+        postBuild = ''
+          rm $out/share/applications/fish.desktop
+        '';
+      }
+    else prev.fish;
+}