6 files changed, 132 insertions, 0 deletions
diff --git a/parts/modules/darwin/base/default.nix b/parts/modules/darwin/base/default.nix
new file mode 100644
index 0000000..42c0335
--- /dev/null
+++ b/parts/modules/darwin/base/default.nix
@@ -0,0 +1,32 @@
+{
+  config,
+  lib,
+  ...
+}: let
+  cfg = config.base;
+  inherit (lib) mkDefault mkEnableOption mkIf;
+in {
+  options.base.enable = mkEnableOption "base darwin module";
+
+  imports = [
+    ../../shared
+    ./nix.nix
+    ./packages.nix
+  ];
+
+  config = mkIf cfg.enable {
+    base = {
+      defaultPackages.enable = mkDefault true;
+      defaultLocale.enable = mkDefault true;
+      documentation.enable = mkDefault true;
+      nix-settings.enable = mkDefault true;
+    };
+
+    programs = {
+      bash.enable = true;
+      zsh.enable = true;
+    };
+
+    services.nix-daemon.enable = true;
+  };
+}
diff --git a/parts/modules/darwin/base/nix.nix b/parts/modules/darwin/base/nix.nix
new file mode 100644
index 0000000..c853650
--- /dev/null
+++ b/parts/modules/darwin/base/nix.nix
@@ -0,0 +1,18 @@
+{
+  config,
+  lib,
+  inputs,
+  ...
+}: let
+  inherit (builtins) attrNames map;
+  inherit (lib) mkIf;
+  cfg = config.base.nix-settings;
+
+  channelPath = i: "${inputs.${i}.outPath}";
+
+  mapInputs = fn: map fn (attrNames inputs);
+in {
+  config = mkIf cfg.enable {
+    nix.nixPath = mapInputs (i: "${i}=${channelPath i}");
+  };
+}
diff --git a/parts/modules/darwin/base/packages.nix b/parts/modules/darwin/base/packages.nix
new file mode 100644
index 0000000..97fb77c
--- /dev/null
+++ b/parts/modules/darwin/base/packages.nix
@@ -0,0 +1,12 @@
+{
+  config,
+  lib,
+  ...
+}: let
+  cfg = config.base.defaultPackages;
+  inherit (lib) mkIf;
+in {
+  config = mkIf cfg.enable {
+    programs.vim.enable = true;
+  };
+}
diff --git a/parts/modules/darwin/default.nix b/parts/modules/darwin/default.nix
new file mode 100644
index 0000000..ed9c7e1
--- /dev/null
+++ b/parts/modules/darwin/default.nix
@@ -0,0 +1,6 @@
+_: {
+  imports = [
+    ./base
+    ./desktop
+  ];
+}
diff --git a/parts/modules/darwin/desktop/default.nix b/parts/modules/darwin/desktop/default.nix
new file mode 100644
index 0000000..1f71642
--- /dev/null
+++ b/parts/modules/darwin/desktop/default.nix
@@ -0,0 +1,27 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}: let
+  cfg = config.desktop;
+  inherit (lib) mkDefault mkEnableOption mkIf;
+in {
+  options.desktop = {
+    enable = mkEnableOption "enable desktop darwin support";
+    gpg.enable = mkEnableOption "enable gpg";
+  };
+
+  imports = [
+    ./homebrew.nix
+  ];
+
+  config = mkIf cfg.enable {
+    fonts.fonts = with pkgs;
+      mkDefault [
+        (nerdfonts.override {fonts = ["FiraCode"];})
+      ];
+
+    programs.gnupg.agent.enable = cfg.gpg.enable;
+  };
+}
diff --git a/parts/modules/darwin/desktop/homebrew.nix b/parts/modules/darwin/desktop/homebrew.nix
new file mode 100644
index 0000000..4a58ae9
--- /dev/null
+++ b/parts/modules/darwin/desktop/homebrew.nix
@@ -0,0 +1,37 @@
+{
+  config,
+  lib,
+  ...
+}: let
+  cfg = config.desktop.homebrew;
+  inherit (lib) mkDefault mkEnableOption mkIf;
+in {
+  options.desktop.homebrew.enable = mkEnableOption "enable homebrew support";
+
+  config = mkIf cfg.enable {
+    homebrew = {
+      enable = mkDefault true;
+      caskArgs.require_sha = true;
+      onActivation = mkDefault {
+        autoUpdate = true;
+        cleanup = "uninstall";
+        upgrade = true;
+      };
+
+      casks = let
+        # thanks @nekowinston :p
+        skipSha = name: {
+          inherit name;
+          args = {require_sha = false;};
+        };
+        noQuarantine = name: {
+          inherit name;
+          args = {no_quarantine = true;};
+        };
+      in [
+        "firefox"
+        (lib.recursiveUpdate (noQuarantine "chromium") (skipSha "chromium"))
+      ];
+    };
+  };
+}