1 files changed, 44 insertions, 0 deletions
diff --git a/systems/deploy.nix b/systems/deploy.nix
new file mode 100644
index 0000000..fbf20d3
--- /dev/null
+++ b/systems/deploy.nix
@@ -0,0 +1,44 @@
+{
+  lib,
+  inputs,
+  self,
+  ...
+}: let
+  targets = ["atlas"];
+  configurations = self.nixosConfigurations // self.darwinConfigurations;
+
+  getDeploy = pkgs:
+    (pkgs.appendOverlays [
+      inputs.deploy.overlay
+      (_: prev: {
+        deploy-rs = {
+          inherit (pkgs) deploy-rs;
+          inherit (prev.deploy-rs) lib;
+        };
+      })
+    ])
+    .deploy-rs;
+
+  toType = system:
+    {
+      "Linux" = "nixos";
+      "Darwin" = "darwin";
+    }
+    .${system};
+
+  toDeployNode = hostname: system: {
+    sshUser = "root";
+    inherit hostname;
+    profiles.system.path = let
+      deploy = getDeploy system.pkgs;
+      type = toType system.pkgs.stdenv.hostPlatform.uname.system;
+    in
+      deploy.lib.activate.${type} system;
+  };
+in {
+  flake.deploy = {
+    remoteBuild = true;
+    fastConnection = false;
+    nodes = lib.mapAttrs toDeployNode (lib.getAttrs targets configurations);
+  };
+}