1 files changed, 43 insertions, 0 deletions
diff --git a/systems/deploy.nix b/systems/deploy.nix
new file mode 100644
index 0000000..186ff37
--- /dev/null
+++ b/systems/deploy.nix
@@ -0,0 +1,43 @@
+{
+  lib,
+  inputs,
+  self,
+  ...
+}: let
+  targets = ["atlas"];
+
+  getDeploy = pkgs:
+    (import pkgs.path {
+      inherit (pkgs) system;
+      overlays = [
+        inputs.deploy.overlay
+        (_: prev: {
+          deploy-rs = {
+            inherit (pkgs) deploy-rs;
+            inherit (prev.deploy-rs) lib;
+          };
+        })
+      ];
+    })
+    .deploy-rs;
+
+  getType = pkgs:
+    if pkgs.stdenv.isDarwin
+    then "darwin"
+    else "nixos";
+
+  toDeployNode = hostname: system: {
+    sshUser = "root";
+    inherit hostname;
+    profiles.system.path = (getDeploy system.pkgs).lib.activate.${getType system.pkgs} system;
+  };
+in {
+  flake.deploy = {
+    remoteBuild = true;
+    fastConnection = false;
+    nodes = lib.pipe (self.nixosConfigurations // self.darwinConfigurations) [
+      (lib.getAttrs targets)
+      (lib.mapAttrs toDeployNode)
+    ];
+  };
+}