1 files changed, 53 insertions, 0 deletions
diff --git a/users/seth/profiles/nixos.nix b/users/seth/profiles/nixos.nix
new file mode 100644
index 0000000..2a91946
--- /dev/null
+++ b/users/seth/profiles/nixos.nix
@@ -0,0 +1,53 @@
+{
+  config,
+  lib,
+  pkgs,
+  osConfig,
+  ...
+}:
+
+let
+  cfg = config.seth.profiles.nixos;
+
+  isNixOSDesktop = osConfig.services.xserver.enable or false;
+  hasSteam = osConfig.programs.steam.enable or false;
+in
+
+{
+  options.seth.profiles.nixos = {
+    enable = lib.mkEnableOption "NixOS profile" // {
+      default = isNixOSDesktop;
+      defaultText = lib.literalExpression "osConfig.services.xserver.enable or false";
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    home.packages = [
+      (pkgs.discord-canary.overrideAttrs (old: {
+        preInstall =
+          old.preInstall or ""
+          + ''
+            gappsWrapperArgs+=(--add-flags "--enable-features=VaapiOnNvidiaGPUs,AcceleratedVideoDecodeLinuxGL")
+          '';
+      }))
+
+      # Matrix client
+      pkgs.element
+
+      pkgs.prismlauncher
+
+      (pkgs.spotify.overrideAttrs {
+        # Spotify doesn't work well on Wayland natively. Don't force it
+        preFixup = ''
+          gappsWrapperArgs+=(--unset NIXOS_OZONE_WL)
+        '';
+      })
+    ];
+
+    programs = {
+      chromium.enable = true;
+      ghostty.enable = true;
+      mangohud.enable = hasSteam;
+    };
+  };
+}