1 files changed, 44 insertions, 0 deletions
diff --git a/users/seth/programs/fish/fish_prompt.fish b/users/seth/programs/fish/fish_prompt.fish
new file mode 100644
index 0000000..5bee872
--- /dev/null
+++ b/users/seth/programs/fish/fish_prompt.fish
@@ -0,0 +1,44 @@
+# SPDX-SnippetCopyrightText: Lily Ballard
+#
+# SPDX-License-Identifier: GPL-2.0-only
+#
+# https://github.com/fish-shell/fish-shell/blob/b570c7f6a6a6b9c5c6638d5bc86943342f7d5b5a/share/functions/fish_prompt.fish
+
+function fish_prompt --description 'Write out the prompt'
+    set -l last_pipestatus $pipestatus
+    set -lx __fish_last_status $status # Export for __fish_print_pipestatus.
+    set -l normal (set_color normal)
+    set -q fish_color_status
+    or set -g fish_color_status red
+
+    # Color the prompt differently when we're root
+    set -l color_cwd $fish_color_cwd
+    set -l suffix '>'
+    if functions -q fish_is_root_user; and fish_is_root_user
+        if set -q fish_color_cwd_root
+            set color_cwd $fish_color_cwd_root
+        end
+        set suffix '#'
+    end
+
+    # Write pipestatus
+    # If the status was carried over (if no command is issued or if `set` leaves the status untouched), don't bold it.
+    set -l bold_flag --bold
+    set -q __fish_prompt_status_generation; or set -g __fish_prompt_status_generation $status_generation
+    if test $__fish_prompt_status_generation = $status_generation
+        set bold_flag
+    end
+    set __fish_prompt_status_generation $status_generation
+    set -l status_color (set_color $fish_color_status)
+    set -l statusb_color (set_color $bold_flag $fish_color_status)
+    set -l prompt_status (__fish_print_pipestatus "[" "]" "|" "$status_color" "$statusb_color" $last_pipestatus)
+
+    set -l snowflake '❄️'
+    set -l nix_shell_info (
+      if test -n "$IN_NIX_SHELL"
+	      echo -n -s $snowflake" "
+	    end
+    )
+
+    echo -n -s (prompt_login)' ' (set_color $color_cwd) (prompt_pwd) $normal (fish_vcs_prompt) $normal " " $nix_shell_info $prompt_status $suffix " "
+end