2 files changed, 57 insertions, 0 deletions
diff --git a/users/seth/tweaks/adwaita-ize.nix b/users/seth/tweaks/adwaita-ize.nix
new file mode 100644
index 0000000..e14277b
--- /dev/null
+++ b/users/seth/tweaks/adwaita-ize.nix
@@ -0,0 +1,52 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+let
+  cfg = config.seth.tweaks.adwaita-ize;
+in
+{
+  options.seth.tweaks.adwaita-ize = {
+    enable = lib.mkEnableOption "libadwaita themeing for non-libadwaita apps";
+
+    adw-gtk3 = lib.mkEnableOption "adw-gtk3 theme for GTK3 apps" // {
+      default = true;
+    };
+    qadwaitadecorations = lib.mkEnableOption "Adwaita CSDs for Qt apps" // {
+      default = true;
+    };
+  };
+
+  config = lib.mkIf cfg.enable (
+    lib.mkMerge [
+      (lib.mkIf cfg.adw-gtk3 {
+        assertions = [
+          {
+            assertion = config.gtk.enable;
+            message = "`gtk.enable` must be `true` to apply the adw-gtk3 theme";
+          }
+        ];
+
+        gtk.theme = {
+          name = "adw-gtk3-dark";
+          package = pkgs.adw-gtk3;
+        };
+      })
+
+      (lib.mkIf cfg.qadwaitadecorations {
+        home = {
+          packages = [
+            pkgs.qadwaitadecorations
+            pkgs.qadwaitadecorations-qt6
+          ];
+
+          sessionVariables = {
+            QT_WAYLAND_DECORATION = "adwaita";
+          };
+        };
+      })
+    ]
+  );
+}
diff --git a/users/seth/tweaks/default.nix b/users/seth/tweaks/default.nix
new file mode 100644
index 0000000..cb8f15c
--- /dev/null
+++ b/users/seth/tweaks/default.nix
@@ -0,0 +1,5 @@
+{
+  imports = [
+    ./adwaita-ize.nix
+  ];
+}