From 4caa14d0416c8ac14e0ac617a1eec22b9df830f6 Mon Sep 17 00:00:00 2001
From: seth <getchoo@tuta.io>
Date: Wed, 28 Feb 2024 07:31:21 -0500
Subject: nixos: remove root password

---
 modules/nixos/server/host-user.nix | 40 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)
 create mode 100644 modules/nixos/server/host-user.nix

(limited to 'modules/nixos/server/host-user.nix')

diff --git a/modules/nixos/server/host-user.nix b/modules/nixos/server/host-user.nix
new file mode 100644
index 0000000..5aa1ce5
--- /dev/null
+++ b/modules/nixos/server/host-user.nix
@@ -0,0 +1,40 @@
+{
+  config,
+  lib,
+  secretsDir,
+  ...
+}: let
+  cfg = config.server.hostUser;
+  inherit (config.networking) hostName;
+in {
+  options.server.hostUser = {
+    enable = lib.mkEnableOption "${hostName} user configuration" // {default = config.server.enable;};
+
+    manageSecrets =
+      lib.mkEnableOption "automatic secrets management"
+      // {
+        default = config.traits.secrets.enable;
+      };
+  };
+
+  config = lib.mkIf cfg.enable (
+    lib.mkMerge [
+      {
+        users.users.${hostName} = {
+          isNormalUser = true;
+          extraGroups = ["wheel"];
+        };
+      }
+
+      (lib.mkIf cfg.manageSecrets {
+        age.secrets = {
+          userPassword.file = secretsDir + "/userPassword.age";
+        };
+
+        users.users.${hostName} = {
+          hashedPasswordFile = config.age.secrets.userPassword.path;
+        };
+      })
+    ]
+  );
+}
-- 
cgit v1.2.3