From dadd33514c1fdc8ba4890e9334ab0fb89c31d02a Mon Sep 17 00:00:00 2001
From: seth <getchoo@tuta.io>
Date: Sun, 11 Feb 2024 03:12:54 -0500
Subject: nixos/server: init (again)

---
 modules/nixos/server/mixins/cloudflared.nix | 50 +++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 modules/nixos/server/mixins/cloudflared.nix

(limited to 'modules/nixos/server/mixins/cloudflared.nix')

diff --git a/modules/nixos/server/mixins/cloudflared.nix b/modules/nixos/server/mixins/cloudflared.nix
new file mode 100644
index 0000000..5f75a35
--- /dev/null
+++ b/modules/nixos/server/mixins/cloudflared.nix
@@ -0,0 +1,50 @@
+{
+  config,
+  lib,
+  secretsDir,
+  ...
+}: let
+  cfg = config.server.mixins.cloudflared;
+  inherit (config.services) nginx;
+in {
+  options.server.mixins.cloudflared = {
+    enable = lib.mkEnableOption "cloudflared mixin";
+    manageSecrets =
+      lib.mkEnableOption "automatic secrets management"
+      // {
+        default = config.traits.secrets.enable;
+      };
+  };
+
+  config = lib.mkIf cfg.enable (
+    lib.mkMerge [
+      {
+        services.cloudflared = {
+          enable = true;
+          tunnels = {
+            "${config.networking.hostName}-nginx" =
+              {
+                default = "http_status:404";
+
+                ingress = lib.genAttrs (builtins.attrNames nginx.virtualHosts) (
+                  _: {service = "http://localhost:${toString nginx.defaultHTTPListenPort}";}
+                );
+              }
+              // lib.optionalAttrs cfg.manageSecrets {
+                credentialsFile = config.age.secrets.cloudflaredCreds.path;
+              };
+          };
+        };
+      }
+
+      (lib.mkIf cfg.manageSecrets {
+        age.secrets.cloudflaredCreds = {
+          file = secretsDir + "/cloudflaredCreds.age";
+          mode = "400";
+          owner = "cloudflared";
+          group = "cloudflared";
+        };
+      })
+    ]
+  );
+}
-- 
cgit v1.2.3