From cffffeb678e9a1078eeba0f19c9607cda9f31bed Mon Sep 17 00:00:00 2001
From: seth <getchoo@tuta.io>
Date: Wed, 7 Feb 2024 18:03:24 -0500
Subject: modules/nixos+darwin: move to traits + archetypes model

---
 modules/nixos/traits/acme.nix | 46 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)
 create mode 100644 modules/nixos/traits/acme.nix

(limited to 'modules/nixos/traits/acme.nix')

diff --git a/modules/nixos/traits/acme.nix b/modules/nixos/traits/acme.nix
new file mode 100644
index 0000000..a377b25
--- /dev/null
+++ b/modules/nixos/traits/acme.nix
@@ -0,0 +1,46 @@
+{
+  config,
+  lib,
+  secretsDir,
+  ...
+}: let
+  cfg = config.traits.acme;
+in {
+  options.traits.acme = {
+    enable = lib.mkEnableOption "ACME support";
+
+    manageSecrets =
+      lib.mkEnableOption "automatic management of secrets"
+      // {
+        default = config.traits.secrets.enable;
+      };
+
+    useDns = lib.mkEnableOption "the usage of dns to get certs" // {default = true;};
+  };
+
+  config = lib.mkIf cfg.enable (
+    lib.mkMerge [
+      {
+        security.acme = {
+          acceptTerms = true;
+          defaults =
+            {
+              email = "getchoo@tuta.io";
+            }
+            // lib.optionalAttrs cfg.useDns {
+              dnsProvider = "cloudflare";
+            }
+            // lib.optionalAttrs cfg.manageSecrets {
+              credentialsFile = config.age.secrets.cloudflareApiKey.path;
+            };
+        };
+      }
+
+      (lib.mkIf cfg.manageSecrets {
+        age.secrets = {
+          cloudflareApiKey.file = secretsDir + "/cloudflareApiKey.age";
+        };
+      })
+    ]
+  );
+}
-- 
cgit v1.2.3