From cffffeb678e9a1078eeba0f19c9607cda9f31bed Mon Sep 17 00:00:00 2001
From: seth <getchoo@tuta.io>
Date: Wed, 7 Feb 2024 18:03:24 -0500
Subject: modules/nixos+darwin: move to traits + archetypes model

---
 modules/nixos/traits/cloudflared.nix | 50 ++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 modules/nixos/traits/cloudflared.nix

(limited to 'modules/nixos/traits/cloudflared.nix')

diff --git a/modules/nixos/traits/cloudflared.nix b/modules/nixos/traits/cloudflared.nix
new file mode 100644
index 0000000..9905d33
--- /dev/null
+++ b/modules/nixos/traits/cloudflared.nix
@@ -0,0 +1,50 @@
+{
+  config,
+  lib,
+  secretsDir,
+  ...
+}: let
+  cfg = config.traits.cloudflared;
+  inherit (config.services) nginx;
+in {
+  options.traits.cloudflared = {
+    enable = lib.mkEnableOption "cloudflared";
+    manageSecrets =
+      lib.mkEnableOption "automatically managed secrets"
+      // {
+        default = config.traits.secrets.enable;
+      };
+  };
+
+  config = lib.mkIf cfg.enable (
+    lib.mkMerge [
+      {
+        services.cloudflared = {
+          enable = true;
+          tunnels = {
+            "${config.networking.hostName}-nginx" =
+              {
+                default = "http_status:404";
+
+                ingress = lib.genAttrs (builtins.attrNames nginx.virtualHosts) (
+                  _: {service = "http://localhost:${toString nginx.defaultHTTPListenPort}";}
+                );
+              }
+              // lib.optionalAttrs cfg.manageSecrets {
+                credentialsFile = config.age.secrets.cloudflaredCreds.path;
+              };
+          };
+        };
+      }
+
+      (lib.mkIf cfg.manageSecrets {
+        age.secrets.cloudflaredCreds = {
+          file = secretsDir + "/cloudflaredCreds.age";
+          mode = "400";
+          owner = "cloudflared";
+          group = "cloudflared";
+        };
+      })
+    ]
+  );
+}
-- 
cgit v1.2.3