From cffffeb678e9a1078eeba0f19c9607cda9f31bed Mon Sep 17 00:00:00 2001
From: seth <getchoo@tuta.io>
Date: Wed, 7 Feb 2024 18:03:24 -0500
Subject: modules/nixos+darwin: move to traits + archetypes model

---
 modules/nixos/traits/user-setup.nix | 45 +++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)
 create mode 100644 modules/nixos/traits/user-setup.nix

(limited to 'modules/nixos/traits/user-setup.nix')

diff --git a/modules/nixos/traits/user-setup.nix b/modules/nixos/traits/user-setup.nix
new file mode 100644
index 0000000..a8a4cd6
--- /dev/null
+++ b/modules/nixos/traits/user-setup.nix
@@ -0,0 +1,45 @@
+{
+  config,
+  lib,
+  pkgs,
+  secretsDir,
+  ...
+}: let
+  cfg = config.traits.user-setup;
+in {
+  options.traits.user-setup = {
+    enable = lib.mkEnableOption "basic immutable user & root configurations";
+    manageSecrets =
+      lib.mkEnableOption "automatic management of secrets"
+      // {
+        default = config.traits.secrets.enable;
+      };
+  };
+
+  config = lib.mkIf cfg.enable (
+    lib.mkMerge [
+      {
+        users = {
+          defaultUserShell = pkgs.bash;
+          mutableUsers = false;
+
+          users.root =
+            {
+              home = lib.mkDefault "/root";
+              uid = lib.mkDefault config.ids.uids.root;
+              group = lib.mkDefault "root";
+            }
+            // lib.optionalAttrs cfg.manageSecrets {
+              hashedPasswordFile = config.age.secrets.rootPassword.path;
+            };
+        };
+      }
+
+      (lib.mkIf cfg.manageSecrets {
+        age.secrets = {
+          rootPassword.file = secretsDir + "/rootPassword.age";
+        };
+      })
+    ]
+  );
+}
-- 
cgit v1.2.3