From 34a7a042a36b63eb6b900932b1e420e4b6014a57 Mon Sep 17 00:00:00 2001
From: seth <getchoo@tuta.io>
Date: Sun, 5 May 2024 11:35:18 -0400
Subject: simplify some things (#353)

* flake: drop flake-parts

* flake: add back flake-parts

* flake: use flake module again for configurations
---
 users/seth/shell/fish.nix | 53 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 users/seth/shell/fish.nix

(limited to 'users/seth/shell/fish.nix')

diff --git a/users/seth/shell/fish.nix b/users/seth/shell/fish.nix
new file mode 100644
index 0000000..0b37273
--- /dev/null
+++ b/users/seth/shell/fish.nix
@@ -0,0 +1,53 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}: let
+  cfg = config.seth.shell.fish;
+in {
+  options.seth.shell.fish = {
+    enable = lib.mkEnableOption "Fish configuration" // {default = config.seth.enable;};
+    withPlugins = lib.mkEnableOption "Fish plugins" // {default = true;};
+  };
+
+  config = lib.mkIf cfg.enable {
+    programs.fish = lib.mkMerge [
+      {
+        enable = true;
+        catppuccin.enable = true;
+
+        interactiveShellInit = ''
+          set -l nixfile ${config.home.homeDirectory}/.nix-profile/etc/profile.d/nix.fish
+          if test -e $nixfile
+          	source $nixfile
+          end
+
+          ${lib.getExe pkgs.nix-your-shell} fish | source
+
+          abbr -a !! --position anywhere --function last_history_item
+        '';
+
+        functions = {
+          last_history_item.body = "echo $history[1]";
+        };
+
+        shellAbbrs = {
+          nixgc = "sudo nix-collect-garbage -d && nix-collect-garbage -d";
+        };
+      }
+
+      (lib.mkIf cfg.withPlugins {
+        plugins = let
+          mkFishPlugins = builtins.map (plugin: {
+            name = plugin;
+            inherit (pkgs.fishPlugins.${plugin}) src;
+          });
+        in
+          mkFishPlugins [
+            "autopair"
+          ];
+      })
+    ];
+  };
+}
-- 
cgit v1.2.3