blob: 7980b8a9d4205b3e4535f1efb06a524be72a2164 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
|
{
config,
lib,
withSystem,
inputs,
...
}: let
namespace = "configurations";
cfg = config.${namespace};
inherit
(lib)
genAttrs
literalExpression
mapAttrs
mdDoc
mkOption
recursiveUpdate
types
;
builderType = types.functionTo pkgsType;
modulesType = types.listOf types.unspecified;
pkgsType = types.lazyAttrsOf types.raw;
kernelFor = type:
{
nixos = "linux";
darwin = "darwin";
}
.${type};
builderStringFor = type:
{
nixos = "inputs.nixpkgs.lib.nixosSystem";
darwin = "inputs.nix-darwin.lib.darwinSystem";
}
.${type};
inputsFor = system: withSystem system ({inputs', ...}: inputs');
mkSystem = type: name: let
args = cfg.${type}.systems.${name};
in
args.builder (lib.recursiveUpdate (removeAttrs args ["builder"]) {
modules =
[
../../systems/${name}
{networking.hostName = name;}
]
++ cfg.${type}.modules
++ args.modules;
specialArgs = {
inherit inputs;
inputs' = inputsFor args.system;
secretsDir = ../../secrets/${name};
};
});
mkUser = name: let
args = cfg.home.users.${name};
in
args.builder (recursiveUpdate (removeAttrs args ["builder"]) {
inherit (args) pkgs;
modules =
[
../../users/${name}/home.nix
{
_module.args.osConfig = {};
programs.home-manager.enable = true;
}
]
++ cfg.home.modules
++ args.modules;
extraSpecialArgs = {
inherit inputs;
inputs' = inputsFor args.pkgs.stdenv.hostPlatform.system;
};
});
mapSystems = type: mapAttrs (name: _: mkSystem type name) cfg.${type}.systems;
mapUsers = mapAttrs (name: _: mkUser name) cfg.home.users;
systemsSubmodule = type: {
options = {
builder = mkOption {
type = builderType;
default = cfg.${type}.builder;
example = literalExpression (builderStringFor type);
description = mdDoc ''
Function to build this ${type}Configuration with
'';
};
modules = mkOption {
type = modulesType;
default = [];
example = literalExpression "[ self.${type}Modules.default ]";
description = mdDoc ''
Extra modules to add to this ${type}Configuration
'';
};
system = mkOption {
type = types.str;
default = "x86_64-${kernelFor type}";
example = literalExpression "aarch64-${kernelFor type}";
description = mdDoc ''
System to build this ${type}Configuration for
'';
};
};
};
usersSubmodule = {
options = {
builder = mkOption {
type = builderType;
default = cfg.home.builder;
example = literalExpression "inputs.home-manager.lib.homeManagerConfiguration";
description = mdDoc ''
Function to build this homeConfiguration with
'';
};
modules = mkOption {
type = modulesType;
default = [];
example = literalExpression "[ self.hmModules.default ]";
description = mdDoc ''
Extra modules to add to this homeConfiguration
'';
};
pkgs = mkOption {
type = pkgsType;
default = cfg.home.pkgs;
example = literalExpression "inputs.nixpkgs.legacyPackages.aarch64-linux";
description = mdDoc ''
Instance of nixpkgs to use in this homeConfiguration
'';
};
};
};
mkSystemOptions = type: {
builder = mkOption {
type = builderType;
example = literalExpression (builderStringFor type);
description = mdDoc ''
Default function to build ${type}Configurations with
'';
};
modules = mkOption {
type = modulesType;
default = [];
example = literalExpression "[ self.${type}Modules.default ]";
description = mdDoc ''
List of modules to add to all ${type}Configurations
'';
};
systems = mkOption {
type = types.attrsOf (types.submodule (systemsSubmodule type));
default = {};
example = literalExpression ''
{
foo = {
system = "aarch64-${kernelFor type}";
};
}
'';
description = mdDoc ''
Attribute set of ${type}Configuration definitions
'';
};
};
in {
options.${namespace} =
genAttrs ["nixos" "darwin"] mkSystemOptions
// {
home = {
builder = mkOption {
type = builderType;
example = literalExpression "inputs.home-manager.lib.homeManagerConfiguration";
description = mdDoc ''
Default function to build homeConfigurations with
'';
};
modules = mkOption {
type = modulesType;
default = [];
example = literalExpression "[ self.homeModules.default ]";
description = mdDoc ''
List of modules to add to all homeConfigurations
'';
};
pkgs = mkOption {
type = pkgsType;
example = literalExpression "inputs.nixpkgs.legacyPackages.aarch64-linux";
description = mdDoc ''
Default instance of nixpkgs to use in homeConfigurations
'';
};
users = mkOption {
type = types.attrsOf (types.submodule usersSubmodule);
default = {};
example = literalExpression ''
{
john = {
pkgs = inputs.nixpkgs.legacyPackages.aarch64-linux;
};
}
'';
description = mdDoc ''
Attribute set of homeConfiguration definitions
'';
};
};
};
config.flake = {
nixosConfigurations = mapSystems "nixos";
darwinConfigurations = mapSystems "darwin";
homeConfigurations = mapUsers;
};
}
|
