modules/nixos/base/users.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

{
  config,
  lib,
  pkgs,
  secretsDir,
  ...
}:
let
  cfg = config.base.users;
in
{
  options.base.users = {
    enable = lib.mkEnableOption "base user configurations" // {
      default = true;
    };

    defaultRoot = {
      enable = lib.mkEnableOption "default root user configuration" // {
        default = false;
      };
      manageSecrets = lib.mkEnableOption "automatic secrets management" // {
        default = config.traits.secrets.enable;
      };
    };
  };

  config = lib.mkIf cfg.enable (
    lib.mkMerge [
      {
        users = {
          defaultUserShell = pkgs.bash;
          mutableUsers = false;
        };
      }

      (lib.mkIf cfg.defaultRoot.enable {
        users.users.root = {
          home = lib.mkDefault "/root";
          uid = lib.mkDefault config.ids.uids.root;
          group = lib.mkDefault "root";
        };
      })

      (lib.mkIf (cfg.defaultRoot.enable && cfg.defaultRoot.manageSecrets) {
        age.secrets = {
          rootPassword.file = secretsDir + "/rootPassword.age";
        };

        users.users.root = {
          hashedPasswordFile = config.age.secrets.rootPassword.path;
        };
      })
    ]
  );
}