modules/nixos/server/mixins/promtail.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

{ config, lib, ... }:
let
  cfg = config.server.mixins.promtail;
  inherit (lib) types;
in
{
  options.server.mixins.promtail = {
    enable = lib.mkEnableOption "Promtail mixin";

    clients = lib.mkOption {
      type = types.listOf types.attrs;
      default = [ { } ];
      description = "Clients for promtail";
    };
  };

  config = lib.mkIf cfg.enable {
    services.promtail = {
      enable = true;
      configuration = {
        inherit (cfg) clients;
        server.disable = true;

        scrape_configs = [
          {
            job_name = "journal";

            journal = {
              max_age = "12h";
              labels = {
                job = "systemd-journal";
                host = "${config.networking.hostName}";
              };
            };

            relabel_configs = [
              {
                source_labels = [ "__journal__systemd_unit" ];
                target_label = "unit";
              }
            ];
          }
        ];
      };
    };
  };
}