1 files changed, 0 insertions, 67 deletions
diff --git a/pkgs/modrinth-app/wrapper.nix b/pkgs/modrinth-app/wrapper.nix
deleted file mode 100644
index 843f499..0000000
--- a/pkgs/modrinth-app/wrapper.nix
+++ /dev/null
@@ -1,67 +0,0 @@
-{
-  lib,
-  stdenv,
-  symlinkJoin,
-  modrinth-app-unwrapped,
-  wrapGAppsHook,
-  addOpenGLRunpath,
-  flite,
-  glib-networking,
-  jdk8,
-  jdk17,
-  jdks ? [jdk8 jdk17],
-  libGL,
-  libpulseaudio,
-  udev,
-  xorg,
-}:
-symlinkJoin {
-  name = "modrinth-app-${modrinth-app-unwrapped.version}";
-
-  paths = [modrinth-app-unwrapped];
-
-  buildInputs = [
-    glib-networking
-  ];
-
-  nativeBuildInputs = [
-    wrapGAppsHook
-  ];
-
-  postBuild = let
-    libPath = lib.makeLibraryPath [
-      flite # narrator support
-      libGL
-      libpulseaudio
-      stdenv.cc.cc.lib
-
-      udev # oshi
-
-      # lwjgl
-      xorg.libX11
-      xorg.libXcursor
-      xorg.libXext
-      xorg.libXxf86vm
-      xorg.libXrandr
-    ];
-
-    binPath = lib.makeBinPath (
-      lib.optionals stdenv.isLinux [xorg.xrandr]
-    );
-
-    args =
-      ["--prefix PATH : ${lib.makeSearchPath "bin/java" jdks}"]
-      ++ lib.optionals stdenv.isLinux [
-        "--set LD_LIBRARY_PATH ${addOpenGLRunpath.driverLink}/lib:${libPath}"
-        "--prefix PATH : ${binPath}"
-      ];
-  in ''
-    gappsWrapperArgs+=(
-      ${lib.concatStringsSep "\n" args}
-    )
-
-    wrapGAppsHook
-  '';
-
-  inherit (modrinth-app-unwrapped) meta;
-}