blob: 7a2e32646715d9ba75b59a1fd59fe8df6efdfa08 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
|
{
config,
lib,
inputs,
...
}:
let
cfg = config.lwjgl;
lwjglVersionSubmodule =
{ name, ... }:
{
freeformType = lib.types.attrsOf lib.types.anything;
options = {
version = lib.mkOption {
type = lib.types.str;
default = name;
defaultText = lib.literalExpression "config.name";
description = "Version of LWJGL3 these arguments are for.";
};
hash = lib.mkOption {
type = lib.types.str;
description = "Hash of the LWJGL3 source tarball.";
};
antHash = lib.mkOption {
type = lib.types.str;
description = "Hash of the LWJGL3 ant dependencies.";
};
};
};
lwjglSubmodule = {
options = {
targets = lib.mkOption {
type = lib.types.listOf lib.types.str;
description = "A list of target triples to cross compile LWJGL3 for.";
};
versions = lib.mkOption {
type = lib.types.attrsOf (lib.types.submodule lwjglVersionSubmodule);
default = { };
description = "An attribute set of LWJGL3 versions and hashes.";
};
};
};
in
{
options.lwjgl = lib.mkOption {
type = lib.types.submodule lwjglSubmodule;
default = { };
description = "Configuration for the LWJGL3 project.";
};
config = {
perSystem =
{
pkgs,
system,
self',
...
}:
let
nativeTarget = pkgs.stdenv.hostPlatform.config;
fetchAntDeps = pkgs.callPackage ./pkgs/fetch-ant-deps.nix { };
# Loop over each target
forAllTargets = lib.genAttrs cfg.targets;
# Nixpkgs re-instantiated to cross compile from our current system to each target
crossPkgsFor = forAllTargets (
target:
if target == nativeTarget then
pkgs
else
import inputs.nixpkgs {
inherit system;
inherit (pkgs) config overlays;
crossSystem = {
config = target;
};
}
);
# Our package set for each target
ourPackagesFor = forAllTargets (
target:
let
lwjgls = lib.mapAttrs' (
version: args:
lib.nameValuePair "${target}-lwjgl-${version}" (
crossPkgsFor.${target}.callPackage (import ./pkgs/lwjgl args) { inherit fetchAntDeps; }
)
) cfg.versions;
versions = lib.naturalSort (lib.attrNames lwjgls);
in
{
# Use latest version by default
lwjgl = lwjgls.${lib.elemAt versions (lib.length versions - 1)};
}
// lwjgls
);
in
{
packages = lib.mergeAttrsList (
(lib.attrValues ourPackagesFor)
++ [
{
lwjgl =
ourPackagesFor.${nativeTarget}.lwjgl
or (lib.trace "${nativeTarget} is not a supported target" pkgs.emptyFile);
default = self'.packages.lwjgl;
}
]
);
};
};
}
|
