nix/derivation.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62

{
  lib,
  stdenv,
  naersk,
  darwin,
  self,
  lto ? false,
  optimizeSize ? false,
}:
naersk.buildPackage {
  pname = "teawiebot";
  version =
    toString (lib.importTOML ../Cargo.toml).package.version
    + "-${self.shortRev or self.dirtyShortRev or "dirty"}";

  src = lib.fileset.toSource {
    root = ../.;
    fileset = lib.fileset.unions [
      ../src
      ../Cargo.toml
      ../Cargo.lock
      ../build.rs
    ];
  };

  buildInputs = lib.optionals stdenv.isDarwin (with darwin.apple_sdk.frameworks; [
    CoreFoundation
    Security
    SystemConfiguration
  ]);

  env = {
    GIT_SHA = self.shortRev or self.dirtyShortRev or "unknown-dirty";
    CARGO_BUILD_RUSTFLAGS = lib.concatStringsSep " " (
      lib.optionals lto [
        "-C"
        "lto=thin"
        "-C"
        "embed-bitcode=yes"
        "-Zdylib-lto"
      ]
      ++ lib.optionals optimizeSize [
        "-C"
        "codegen-units=1"
        "-C"
        "panic=abort"
        "-C"
        "strip=symbols"
        "-C"
        "opt-level=z"
      ]
    );
  };

  meta = with lib; {
    mainProgram = "teawiebot";
    description = "funni bot";
    homepage = "https://github.com/getchoo/teawiebot";
    license = licenses.mit;
    maintainers = with maintainers; [getchoo];
  };
}