nix/package.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60

{
  lib,
  rustPlatform,
  self ? { },
  lto ? true,
  optimizeSize ? false,
}:

let
  fs = lib.fileset;
in

rustPlatform.buildRustPackage {
  pname = "chill-discord-bot";
  version = (lib.importTOML ../Cargo.toml).package.version or "unknown";

  src = fs.toSource {
    root = ../.;
    fileset = fs.intersection (fs.gitTracked ../.) (
      lib.fileset.unions [
        ../src
        ../Cargo.toml
        ../Cargo.lock
      ]
    );
  };

  cargoLock.lockFile = ../Cargo.lock;

  # `-C panic="abort"` breaks checks
  doCheck = !optimizeSize;

  RUSTFLAGS =
    lib.optionals lto [
      "-C"
      "embed-bitcode=yes"
      "-C"
      "lto=thin"
    ]
    ++ lib.optionals optimizeSize [
      "-C"
      "codegen-units=1"
      "-C"
      "opt-level=s"
      "-C"
      "panic=abort"
      "-C"
      "strip=symbols"
    ];

  GIT_SHA = self.shortRev or self.dirtyShortRev or "unknown";

  meta = {
    description = "funni bot";
    homepage = "https://github.com/getchoo/chill";
    license = lib.licenses.mit;
    maintainers = with lib.maintainers; [ getchoo ];
    mainProgram = "chill";
  };
}