flake.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81

{
  inputs = {
    nixpkgs.url = "nixpkgs/nixpkgs-unstable";

    parts = {
      url = "github:hercules-ci/flake-parts";
      inputs.nixpkgs-lib.follows = "nixpkgs";
    };

    pre-commit = {
      url = "github:cachix/pre-commit-hooks.nix";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.nixpkgs-stable.follows = "nixpkgs";
    };
  };

  outputs = {
    parts,
    pre-commit,
    ...
  } @ inputs:
    parts.lib.mkFlake {inherit inputs;} {
      systems = [
        "x86_64-linux"
        "aarch64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];

      imports = [pre-commit.flakeModule];

      perSystem = {
        config,
        pkgs,
        ...
      }: {
        devShells.default = pkgs.mkShell {
          shellHook = ''
            [ ! -d node_modules ] && pnpm install --frozen-lockfile
            ${config.pre-commit.installationScript}
          '';

          packages = with pkgs; [
            nodejs_20
            (nodePackages_latest.pnpm.override {nodejs = nodejs_20;})

            actionlint
            editorconfig-checker

            config.formatter
            deadnix
            nil
            statix
          ];
        };

        formatter = pkgs.alejandra;

        pre-commit.settings = {
          hooks = {
            actionlint.enable = true;
            editorconfig-checker.enable = true;

            # typescript
            eslint.enable = true;
            prettier.enable = true;

            # nix
            ${config.formatter.pname}.enable = true;
            deadnix.enable = true;
            nil.enable = true;
            statix.enable = true;
          };

          settings = {
            eslint.extensions = "\\.(js|jsx|ts|tsx)$";
          };
        };
      };
    };
}