flake.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70

{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";

    treefmt-nix = {
      url = "github:numtide/treefmt-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      treefmt-nix,
    }:
    let
      inherit (nixpkgs) lib;
      systems = [
        "x86_64-linux"
        "aarch64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];

      forAllSystems = lib.genAttrs systems;
      nixpkgsFor = forAllSystems (system: nixpkgs.legacyPackages.${system});
      treefmtFor = forAllSystems (system: treefmt-nix.lib.evalModule nixpkgsFor.${system} ./treefmt.nix);
    in
    {
      checks = forAllSystems (system: {
        treefmt = treefmtFor.${system}.config.build.check self;
      });

      devShells = forAllSystems (
        system:
        let
          pkgs = nixpkgsFor.${system};

          basePackages = [
            pkgs.nodejs
            pkgs.corepack

            pkgs.nrr
            pkgs.wrangler
          ];
        in
        {
          default = pkgs.mkShellNoCC {
            packages = basePackages ++ [
              pkgs.typescript-language-server
              pkgs.vscode-langservers-extracted # for eslint server

              # github actions
              pkgs.actionlint

              # nix
              self.formatter.${system}
              pkgs.nil
              pkgs.statix
            ];
          };

          ci = pkgs.mkShellNoCC { packages = basePackages; };
        }
      );

      formatter = forAllSystems (system: treefmtFor.${system}.config.build.wrapper);
    };
}