tree-wide: refactor

i went overboard on modules. this is much comfier

1 files changed, 40 insertions, 0 deletions

diff --git a/modules/nixos/services/cloudflared.nix b/modules/nixos/services/cloudflared.nix
new file mode 100644
index 0000000..a144266
--- /dev/null
+++ b/modules/nixos/services/cloudflared.nix
@@ -0,0 +1,40 @@
+{
+  config,
+  lib,
+  ...
+}: let
+  cfg = config.server.services.cloudflared;
+  inherit (lib) mkEnableOption mkIf;
+in {
+  options.server.services.cloudflared = {
+    enable = mkEnableOption "cloudflared";
+  };
+
+  config = mkIf cfg.enable {
+    age.secrets.cloudflaredCreds = {
+      file = ../../../secrets/systems/${config.networking.hostName}/cloudflaredCreds.age;
+      mode = "400";
+      owner = "cloudflared";
+      group = "cloudflared";
+    };
+
+    services.cloudflared = {
+      enable = true;
+      tunnels = {
+        "${config.networking.hostName}-nginx" = {
+          default = "http_status:404";
+
+          ingress = let
+            inherit (config.services) nginx;
+          in
+            lib.genAttrs
+            (builtins.attrNames nginx.virtualHosts)
+            (_: {service = "http://localhost:${builtins.toString nginx.defaultHTTPListenPort}";});
+
+          originRequest.noTLSVerify = true;
+          credentialsFile = config.age.secrets.cloudflaredCreds.path;
+        };
+      };
+    };
+  };
+}