flake: restructure a lot

4 files changed, 115 insertions, 1 deletions

diff --git a/modules/server/default.nix b/modules/server/default.nix
index cce7625..9692a82 100644
--- a/modules/server/default.nix
+++ b/modules/server/default.nix
@@ -9,6 +9,11 @@
 in {
   options.getchoo.server.enable = mkEnableOption "enable server configuration";
 
+  imports = [
+    ./secrets.nix
+    ./services
+  ];
+
   config = mkIf cfg.enable {
     getchoo = {
       base = {
@@ -34,7 +39,25 @@ in {
       };
     };
 
-    nix.gc.options = "--delete-older-than 7d --max-freed 50G";
+    nix = {
+      gc.options = "--delete-older-than 7d --max-freed 50G";
+      settings = {
+        trusted-users = ["${config.networking.hostName}"];
+        trusted-substituters = [
+          "https://getchoo.cachix.org"
+          "https://nix-community.cachix.org"
+          "https://hercules-ci.cachix.org"
+          "https://wurzelpfropf.cachix.org"
+        ];
+
+        trusted-public-keys = [
+          "getchoo.cachix.org-1:ftdbAUJVNaFonM0obRGgR5+nUmdLMM+AOvDOSx0z5tE="
+          "nix-community.cachix.org-1:mB9FSh9qf2dCimDSUo8Zy7bkq5CX+/rkCWyvRCYg3Fs="
+          "hercules-ci.cachix.org-1:ZZeDl9Va+xe9j+KqdzoBZMFJHVQ42Uu/c/1/KMC5Lw0="
+          "wurzelpfropf.cachix.org-1:ilZwK5a6wJqVr7Fyrzp4blIEkGK+LJT0QrpWr1qBNq0="
+        ];
+      };
+    };
 
     programs = {
       git.enable = mkDefault true;
diff --git a/modules/server/secrets.nix b/modules/server/secrets.nix
new file mode 100644
index 0000000..c0290cd
--- /dev/null
+++ b/modules/server/secrets.nix
@@ -0,0 +1,25 @@
+{
+  config,
+  lib,
+  self,
+  ...
+}: let
+  cfg = config.getchoo.server.secrets;
+  inherit (lib) mkEnableOption mkIf;
+in {
+  options.getchoo.server.secrets = {
+    enable = mkEnableOption "enable secret management";
+  };
+
+  config.age = let
+    baseDir = "${self}/secrets/hosts/${config.networking.hostName}";
+  in
+    mkIf cfg.enable {
+      identityPaths = ["/etc/age/key"];
+
+      secrets = {
+        rootPassword.file = "${baseDir}/rootPassword.age";
+        userPassword.file = "${baseDir}/userPassword.age";
+      };
+    };
+}
diff --git a/modules/server/services/default.nix b/modules/server/services/default.nix
new file mode 100644
index 0000000..68271b1
--- /dev/null
+++ b/modules/server/services/default.nix
@@ -0,0 +1,5 @@
+_: {
+  imports = [
+    ./hercules.nix
+  ];
+}
diff --git a/modules/server/services/hercules.nix b/modules/server/services/hercules.nix
new file mode 100644
index 0000000..782e5a8
--- /dev/null
+++ b/modules/server/services/hercules.nix
@@ -0,0 +1,61 @@
+{
+  config,
+  hercules-ci-agent,
+  lib,
+  pkgs,
+  self,
+  ...
+}: let
+  cfg = config.getchoo.server.services.hercules-ci;
+  inherit (lib) mkEnableOption mkIf;
+in {
+  options.getchoo.server.services.hercules-ci = {
+    enable = mkEnableOption "enable hercules-ci";
+    secrets.enable = mkEnableOption "manage secrets for hercules-ci";
+  };
+
+  config = mkIf cfg.enable {
+    age.secrets = let
+      baseDir = "${self}/secrets/hosts/${config.networking.hostName}";
+      hercArgs = {
+        mode = "400";
+        owner = "hercules-ci-agent";
+        group = "hercules-ci-agent";
+      };
+    in
+      mkIf cfg.secrets.enable {
+        binaryCache =
+          {
+            file = "${baseDir}/binaryCache.age";
+          }
+          // hercArgs;
+
+        clusterToken =
+          {
+            file = "${baseDir}/clusterToken.age";
+          }
+          // hercArgs;
+
+        secretsJson =
+          {
+            file = "${baseDir}/secretsJson.age";
+          }
+          // hercArgs;
+      };
+
+    environment.systemPackages = [
+      hercules-ci-agent.packages.${pkgs.stdenv.hostPlatform.system}.hercules-ci-cli
+    ];
+
+    services = {
+      hercules-ci-agent = {
+        enable = true;
+        settings = {
+          binaryCachesPath = config.age.secrets.binaryCache.path;
+          clusterJoinTokenPath = config.age.secrets.clusterToken.path;
+          secretsJsonPath = config.age.secrets.secretsJson.path;
+        };
+      };
+    };
+  };
+}