1 files changed, 41 insertions, 0 deletions
diff --git a/modules/nixos/server/services/cloudflared.nix b/modules/nixos/server/services/cloudflared.nix
new file mode 100644
index 0000000..5081a0a
--- /dev/null
+++ b/modules/nixos/server/services/cloudflared.nix
@@ -0,0 +1,41 @@
+{
+  config,
+  lib,
+  self,
+  ...
+}: let
+  cfg = config.getchoo.server.services.cloudflared;
+  inherit (lib) mkEnableOption mkIf;
+in {
+  options.getchoo.server.services.cloudflared = {
+    enable = mkEnableOption "cloudflared";
+  };
+
+  config = mkIf cfg.enable {
+    age.secrets.cloudflaredCreds = {
+      file = "${self}/secrets/hosts/${config.networking.hostName}/cloudflaredCreds.age";
+      mode = "400";
+      owner = "cloudflared";
+      group = "cloudflared";
+    };
+
+    services.cloudflared = {
+      enable = true;
+      tunnels = {
+        "${config.networking.hostName}-nginx" = {
+          default = "http_status:404";
+
+          ingress = let
+            inherit (config.services) nginx;
+          in
+            lib.genAttrs
+            (builtins.attrNames nginx.virtualHosts)
+            (_: {service = "http://localhost:${builtins.toString nginx.defaultHTTPListenPort}";});
+
+          originRequest.noTLSVerify = true;
+          credentialsFile = config.age.secrets.cloudflaredCreds.path;
+        };
+      };
+    };
+  };
+}