flake/ci.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81

{ self, ... }:

{
  perSystem =
    {
      config,
      lib,
      pkgs,
      self',
      system,
      ...
    }:

    let
      collectNestedDerivations = self.lib.collectNestedDerivationsFor system;
    in

    lib.mkMerge [
      {
        checks = collectNestedDerivations {
          inherit (self)
            nixosConfigurations
            homeConfigurations
            darwinConfigurations
            ;
        };

        legacyPackages = {
          tflint = config.quickChecks.tflint.package;
        };
      }

      # I don't really care to run these on other systems
      (lib.mkIf (system == "x86_64-linux") {
        checks = collectNestedDerivations { inherit (self') devShells; };

        quickChecks = {
          actionlint = {
            dependencies = [ pkgs.actionlint ];
            script = "actionlint ${self}/.github/workflows/**";
          };

          deadnix = {
            dependencies = [ pkgs.deadnix ];
            script = "deadnix --fail ${self}";
          };

          hclfmt = {
            dependencies = [ pkgs.hclfmt ];
            script = "hclfmt -require-no-change ${self}/terraform/*.tf";
          };

          just = {
            dependencies = [ pkgs.just ];
            script = ''
              cd ${self}
              just --check --fmt --unstable
              just --summary
            '';
          };

          nixfmt = {
            dependencies = [ pkgs.nixfmt-rfc-style ];
            script = "nixfmt --check ${self}/**/*.nix";
          };

          statix = {
            dependencies = [ pkgs.statix ];
            script = "statix check ${self}";
          };

          tflint = {
            dependencies = [ pkgs.tflint ];
            script = ''
              tflint --chdir=${self}/terraform --format=sarif |& tee $out || true
            '';
          };
        };
      })
    ];
}