flake/dev-shells.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

{
  perSystem =
    {
      lib,
      pkgs,
      inputs',
      self',
      ...
    }:

    let
      inherit (pkgs.stdenv.hostPlatform) isDarwin isLinux;

      nix = inputs'.lix-module.packages.default;

      overrideNix = p: p.override { inherit nix; };
      nixos-rebuild = overrideNix pkgs.nixos-rebuild;
    in

    {
      devShells = {
        default = pkgs.mkShellNoCC {
          packages =
            [
              # We want to make sure we have the same
              # Nix behavior across machines
              nix

              # For CI
              pkgs.actionlint

              # Nix tools
              pkgs.nil
              pkgs.statix
              self'.formatter

              pkgs.just
              pkgs.opentofu
            ]
            ++ lib.optionals isDarwin [
              inputs'.nix-darwin.packages.darwin-rebuild
            ]
            ++ lib.optionals isLinux [
              # See above comment about Nix
              nixos-rebuild

              inputs'.agenix.packages.agenix
            ];
        };
      };
    };
}