hosts/atlas/nginx.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

{config, ...}: {
  getchoo.server.acme.enable = true;
  networking.firewall.allowedTCPPorts = [443];

  security.acme = {
    acceptTerms = true;
    defaults = {
      email = "[email protected]";
      dnsProvider = "cloudflare";
      credentialsFile = config.age.secrets.cloudflareApiKey.path;
    };
  };

  services.nginx = {
    enable = true;

    recommendedGzipSettings = true;
    recommendedOptimisation = true;
    recommendedProxySettings = true;
    recommendedTlsSettings = true;

    virtualHosts = let
      inherit (config.networking) domain;

      mkProxy = endpoint: port: {
        "${endpoint}" = {
          proxyPass = "http://localhost:${port}";
          proxyWebsockets = true;
        };
      };

      mkVHosts = builtins.mapAttrs (_: v:
        v
        // {
          enableACME = true;
          # workaround for https://github.com/NixOS/nixpkgs/issues/210807
          acmeRoot = null;
          forceSSL = true;
        });
    in
      mkVHosts {
        "miniflux.${domain}" = {
          locations = mkProxy "/" "7000";
        };

        "msix.${domain}" = {
          root = "/var/www/msix";
        };
      };
  };
}