lib/builders.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66

{
  lib,
  inputs,
  self,
  ...
}:
{
  nixosSystem =
    {
      nixpkgs ? inputs.nixpkgs,
      specialArgs ? { },
      ...
    }@args:
    nixpkgs.lib.nixosSystem (
      lib.removeAttrs args [ "nixpkgs" ]
      // {
        specialArgs = specialArgs // {
          inherit inputs;
        };
      }
    );

  darwinSystem =
    {
      nix-darwin ? inputs.nix-darwin or inputs.darwin,
      specialArgs ? { },
      ...
    }@args:
    nix-darwin.lib.darwinSystem (
      lib.removeAttrs args [ "nix-darwin" ]
      // {
        specialArgs = specialArgs // {
          inherit inputs;
        };
      }
    );

  homeManagerConfiguration =
    {
      extraSpecialArgs ? { },
      ...
    }@args:
    inputs.home-manager.lib.homeManagerConfiguration (
      args
      // {
        extraSpecialArgs = extraSpecialArgs // {
          inherit inputs;
        };
      }
    );

  mkModule =
    {
      name,
      type,
      imports,
    }@args:
    {
      _file = "${self.outPath}/flake.nix#${type}Modules.${name}";
      inherit imports;
    }
    // lib.removeAttrs args [
      "name"
      "type"
    ];
}