modules/nixos/server/mixins/hercules.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

{
  config,
  lib,
  unstable,
  secretsDir,
  ...
}:
let
  cfg = config.server.mixins.hercules-ci;
in
{
  options.server.mixins.hercules-ci = {
    enable = lib.mkEnableOption "hercules-ci mixin";
    manageSecrets = lib.mkEnableOption "automatic secrets management" // {
      default = config.traits.secrets.enable;
    };
  };

  config = lib.mkIf cfg.enable (
    lib.mkMerge [
      {
        services.hercules-ci-agent = {
          enable = true;
          package = unstable.hercules-ci-agent;
        };
      }

      (
        let
          secretNames = [
            "binaryCaches"
            "clusterJoinToken"
            "secretsJson"
          ];
        in
        lib.mkIf cfg.manageSecrets {
          age.secrets = lib.genAttrs secretNames (file: {
            file = "${secretsDir}/${file}.age";
            mode = "400";
            owner = "hercules-ci-agent";
            group = "hercules-ci-agent";
          });

          services.hercules-ci-agent = {
            settings = lib.mapAttrs' (name: lib.nameValuePair (name + "Path")) (
              lib.genAttrs secretNames (name: config.age.secrets.${name}.path)
            );
          };
        }
      )
    ]
  );
}