modules/nixos/services/hercules.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

{
  config,
  lib,
  unstable,
  secretsDir,
  ...
}: let
  cfg = config.server.services.hercules-ci;
  inherit (lib) mkEnableOption mkIf;

  hercArgs = {
    mode = "400";
    owner = "hercules-ci-agent";
    group = "hercules-ci-agent";
  };
in {
  options.server.services.hercules-ci = {
    enable = mkEnableOption "hercules-ci";
    secrets.enable = mkEnableOption "secrets management for hercules-ci";
  };

  config = mkIf cfg.enable {
    age.secrets = mkIf cfg.secrets.enable {
      binaryCache =
        {
          file = secretsDir + "/binaryCache.age";
        }
        // hercArgs;

      clusterToken =
        {
          file = secretsDir + "/clusterToken.age";
        }
        // hercArgs;

      secretsJson =
        {
          file = secretsDir + "/secretsJson.age";
        }
        // hercArgs;
    };

    services = {
      hercules-ci-agent = {
        enable = true;
        package = unstable.hercules-ci-agent;
        settings = {
          binaryCachesPath = config.age.secrets.binaryCache.path;
          clusterJoinTokenPath = config.age.secrets.clusterToken.path;
          secretsJsonPath = config.age.secrets.secretsJson.path;
        };
      };
    };
  };
}