modules/nixos/traits/acme.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

{
  config,
  lib,
  secretsDir,
  ...
}: let
  cfg = config.traits.acme;
in {
  options.traits.acme = {
    enable = lib.mkEnableOption "ACME support";

    manageSecrets =
      lib.mkEnableOption "automatic secrets management"
      // {
        default = config.traits.secrets.enable;
      };

    useDns = lib.mkEnableOption "the usage of dns to get certs" // {default = true;};
  };

  config = lib.mkIf cfg.enable (
    lib.mkMerge [
      {
        security.acme = {
          acceptTerms = true;
          defaults =
            {
              email = "[email protected]";
            }
            // lib.optionalAttrs cfg.useDns {
              dnsProvider = "cloudflare";
            }
            // lib.optionalAttrs cfg.manageSecrets {
              credentialsFile = config.age.secrets.cloudflareApiKey.path;
            };
        };
      }

      (lib.mkIf cfg.manageSecrets {
        age.secrets = {
          cloudflareApiKey.file = secretsDir + "/cloudflareApiKey.age";
        };
      })
    ]
  );
}