parts/lib/configs.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

{
  inputs,
  self,
  ...
}: let
  inherit (builtins) attrNames mapAttrs;
  inherit (inputs) nixpkgs hm;
  inherit (nixpkgs.lib) genAttrs optional;

  mkSystemCfg = name: {
    profile,
    modules ? profile.modules,
    system ? profile.system,
    specialArgs ? profile.specialArgs,
  }:
    profile.builder {
      inherit specialArgs system;
      modules =
        [../../hosts/${name}]
        ++ (
          if modules == profile.modules
          then modules
          else modules ++ profile.modules
        );
    };

  mkHMCfg = name: {
    nixpkgs ? nixpkgs,
    pkgs ? import nixpkgs {system = "x86_64-linux";},
    extraSpecialArgs ? inputs,
    modules ? [],
  }:
    hm.lib.homeManagerConfiguration {
      inherit extraSpecialArgs pkgs;

      modules =
        [
          self.homeManagerModules.${name}
          ../../users/${name}/home.nix

          {
            _module.args.osConfig = {};
            programs.home-manager.enable = true;
          }
        ]
        ++ optional pkgs.stdenv.isDarwin ../../users/${name}/darwin.nix
        ++ modules;
    };
in {
  inherit mkHMCfg mkSystemCfg;
  mapHMUsers = mapAttrs mkHMCfg;
  mapSystems = mapAttrs mkSystemCfg;

  genHMModules = users:
    genAttrs (attrNames users) (name: import ../../users/${name}/module.nix);
}