users/seth/profiles/nixos.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

{
  config,
  lib,
  pkgs,
  osConfig,
  ...
}:

let
  cfg = config.seth.profiles.nixos;

  isNixOSDesktop = osConfig.services.xserver.enable or false;
  hasSteam = osConfig.programs.steam.enable or false;
in

{
  options.seth.profiles.nixos = {
    enable = lib.mkEnableOption "NixOS profile" // {
      default = isNixOSDesktop;
      defaultText = lib.literalExpression "osConfig.services.xserver.enable or false";
    };
  };

  config = lib.mkIf cfg.enable {
    home.packages = [
      (pkgs.discord.overrideAttrs (old: {
        # Discord currently uses Chromium 130
        # https://github.com/elFarto/nvidia-vaapi-driver/issues/5#issuecomment-2421082537
        preInstall =
          old.preInstall or ""
          + ''
            gappsWrapperArgs+=(--add-flags "--enable-features=VaapiOnNvidiaGPUs,VaapiVideoDecodeLinuxGL,VaapiVideoDecodeLinuxZeroCopyGL")
          '';
      }))

      # Matrix client
      pkgs.element-desktop

      pkgs.prismlauncher

      (pkgs.spotify.overrideAttrs {
        # Spotify doesn't work well on Wayland natively. Don't force it
        preFixup = ''
          gappsWrapperArgs+=(--unset NIXOS_OZONE_WL)
        '';
      })
    ];

    programs = {
      chromium.enable = true;
      firefox.enable = true;
      ghostty.enable = true;
      mangohud.enable = hasSteam;
    };
  };
}