users/seth/programs/fish.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72

{
  config,
  lib,
  pkgs,
  ...
}:
let
  cfg = config.seth.programs.fish;
in
{
  options.seth.programs.fish = {
    enable = lib.mkEnableOption "Fish configuration";
    hydro.enable = lib.mkEnableOption "Hydra prompt" // {
      default = true;
    };
  };

  config = lib.mkIf cfg.enable (
    lib.mkMerge [
      {
        programs.fish = {
          enable = true;

          functions = {
            last_history_item.body = "echo $history[1]";
          };

          shellAbbrs = {
            nixgc = "sudo nix-collect-garbage -d && nix-collect-garbage -d";
            "!!" = {
              position = "anywhere";
              function = "last_history_item";
            };
          };
        };
      }

      (lib.mkIf cfg.hydro.enable {
        programs.fish = {
          interactiveShellInit = ''
            set --global hydro_symbol_prompt ">"

            set --global hydro_color_duration $fish_color_end
            set --global hydro_color_error $fish_color_error
            set --global hydro_color_git cba6f7
            set --global hydro_color_prompt $fish_color_cwd
            set --global hydro_color_pwd $fish_color_user
          '';

          plugins = [
            {
              name = "hydro";
              inherit (pkgs.fishPlugins.hydro) src;
            }
          ];
        };
      })

      # TODO: do i still need this weird sourcing?
      (lib.mkIf config.seth.standalone.enable {
        programs.fish = {
          interactiveShellInit = ''
            set -l nixfile ${config.home.homeDirectory}/.nix-profile/etc/profile.d/nix.fish
            if test -e $nixfile
            	source $nixfile
            end
          '';
        };
      })
    ]
  );
}