users/seth/shell/fish.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

{
  config,
  lib,
  pkgs,
  ...
}:
let
  cfg = config.seth.shell.fish;
in
{
  options.seth.shell.fish = {
    enable = lib.mkEnableOption "Fish configuration";
    withPlugins = lib.mkEnableOption "Fish plugins" // {
      default = true;
    };
  };

  config = lib.mkIf cfg.enable {
    programs.fish = lib.mkMerge [
      {
        enable = true;

        # TODO: do i still need this weird sourcing?
        interactiveShellInit = lib.optionalString config.seth.standalone.enable ''
          set -l nixfile ${config.home.homeDirectory}/.nix-profile/etc/profile.d/nix.fish
          if test -e $nixfile
          	source $nixfile
          end
        '';

        functions = {
          last_history_item.body = "echo $history[1]";
        };

        shellAbbrs = {
          nixgc = "sudo nix-collect-garbage -d && nix-collect-garbage -d";
          "!!" = {
            position = "anywhere";
            function = "last_history_item";
          };
        };
      }

      (lib.mkIf cfg.withPlugins {
        plugins =
          let
            mkFishPlugins = map (plugin: {
              name = plugin;
              inherit (pkgs.fishPlugins.${plugin}) src;
            });
          in
          mkFishPlugins [ "autopair" ];
      })
    ];
  };
}