checks.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

{
  pkgs,
  self,
}: let
  inherit (pkgs) lib;
  formatter = self.formatter.${pkgs.system};
in {
  check-actionlint =
    pkgs.runCommand "check-actionlint" {
      nativeBuildInputs = [pkgs.actionlint];
    } ''
      actionlint ${./.}/.github/workflows/*
      touch $out
    '';

  "check-${formatter.pname}" =
    pkgs.runCommand "check-${formatter.pname}" {
      nativeBuildInputs = [formatter];
    } ''
      ${lib.getExe formatter} --check ${./.}
      touch $out
    '';

  check-statix =
    pkgs.runCommand "check-statix" {
      nativeBuildInputs = [pkgs.statix];
    }
    ''
      statix check ${./.}
      touch $out
    '';

  check-nil =
    pkgs.runCommand "check-nil" {
      nativeBuildInputs = with pkgs; [fd git nil];
    }
    ''
      cd ${./.}
      fd . -e 'nix' | while read -r file; do
        nil diagnostics "$file"
      done

      touch $out
    '';

  check-stylua = pkgs.runCommand "check-stylua" {} ''
    ${lib.getExe pkgs.stylua} --check ${./.}

    touch $out
  '';
}