checks.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

{
  lib,
  inputs,
  self,
  ...
}:

let
  collectNestedDerivationsIn = lib.foldlAttrs (
    acc: attrType: values:

    acc // lib.mapAttrs' (attrName: lib.nameValuePair "${attrType}-${attrName}") values
  ) { };
in

{
  imports = [ inputs.getchpkgs.flakeModules.checks ];

  perSystem =
    {
      pkgs,
      system,
      self',
      ...
    }:

    lib.mkMerge [
      {
        checks = collectNestedDerivationsIn { inherit (self') devShells packages; };
      }

      (lib.mkIf (system == "x86_64-linux") {
        quickChecks = {
          deadnix = {
            dependencies = [ pkgs.deadnix ];
            script = "deadnix --fail ${self}";
          };

          nixfmt = {
            dependencies = [ pkgs.nixfmt-rfc-style ];
            script = "nixfmt --check ${self}";
          };

          statix = {
            dependencies = [ pkgs.statix ];
            script = "statix check ${self}";
          };
        };
      })
    ];
}