default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67

{
  pkgs ? import nixpkgs {
    inherit system;
    config = { };
    overlays = [ ];
  },
  nixpkgs ? <nixpkgs>,
  system ? builtins.currentSystem,
}:
{
  website = pkgs.callPackage (
    {
      lib,
      stdenvNoCC,
      writeShellApplication,
      zola,
    }:
    stdenvNoCC.mkDerivation {
      name = "getchoo-website";

      src = lib.fileset.toSource {
        root = ./.;
        fileset = lib.fileset.unions [
          ./config.toml
          ./content
          ./highlight_themes
          ./static
          ./templates
        ];
      };

      nativeBuildInputs = [ zola ];

      dontConfigure = true;
      doCheck = false;

      buildPhase = ''
        runHook preBuild
        zola build
        runHook postBuild
      '';

      installPhase = ''
        runHook preInstall
        mv public $out
        runHook postInstall
      '';

      passthru = {
        serve = writeShellApplication {
          name = "serve";
          runtimeInputs = [ zola ];

          text = ''
            zola serve
          '';
        };
      };

      meta = {
        homepage = "https://github.com/getchoo/website";
        license = lib.licenses.mit;
        maintainers = with lib.maintainers; [ getchoo ];
      };
    }
  ) { };
}